CODIGO.actionscript » Básico

Cómo crear transiciones entre fotogramas en Flash

admin — Tue, 19 Jan 2010 03:33:19 +0000

Hace unos días me preguntaron como crear transiciones entre fotogramas en Flash. Esto es una tarea bastante sencilla de implementar así que aprovecho para explicarla en forma de Tip.

Lo que se pretende conseguir es que al cambiar de fotograma, los elementos del fotograma actual desaparezcan de forma animada antes de saltar al siguiente fotograma. Como se ve en el ejemplo:

Clicka en los botones de colores

Esta sencilla película está estructurada en varios fotogramas con un elemento diferente en cada uno de ellos y una serie de botones que nos hacen saltar de uno a otro.

La idea del ejemplo es que cada fotograma esté contenido en un MovieClip que contenga a su vez la animación de entrada y salida. Y por código haremos que se reproduzcan estas animaciones al cambiar de fotograma.

En el primer fotograma del MovieClip tendremos todo su contenido tal cual nos interese tener en pantalla, y apartir del segundo fotograma haremos la animación de entrada y salida.

Para este ejemplo la animación de entrada y salida será la misma interpolación de movimiento que reproduciremos adelante o hacia atrás según sea el caso.

Para poder referenciar el código colocaremos un Label "on" en el primer frame de la animación, un Label "anim" en los fotogramas internos de la animación, y un Label "out" en el último fotograma de la animación.

[h3]Ahora vayamos al código:[/h3]

Empezaremos por la clase Main.as, que es la clase de la pelicula y donde asignaremos los comportamientos a los botones:

package {
import flash.display.MovieClip;
import flash.events.MouseEvent;
//
public class Main extends MovieClip {

public var currentFrameClip:MovieClip;

public function Main() {
this.boton1.addEventListener(MouseEvent.CLICK,gotoFrame);
this.boton2.addEventListener(MouseEvent.CLICK,gotoFrame);
this.boton3.addEventListener(MouseEvent.CLICK,gotoFrame);
this.boton4.addEventListener(MouseEvent.CLICK,gotoFrame);
this.stop();
}
private function gotoFrame(e:MouseEvent):void {
switch (e.currentTarget) {
case boton1 :
currentFrameClip.gotoFrame(1);
break;
case boton2 :
currentFrameClip.gotoFrame(2);
break;
case boton3 :
currentFrameClip.gotoFrame(3);
break;
case boton4 :
currentFrameClip.gotoFrame(4);
break;
}
}
}
}

Aquí lo único que hacemos es que los botones de la película hagan ejecutar al MovieClip, referenciado desde una variable "currentFrameClip", un método llamado "gotoFrame", que como su nombre indica nos hará saltar al fotograma pasado como parámetro.

Vayamos ahora a la clase que asignaremos a cada uno de los MovieClip de los fotogramas y que es la que hará reproducir la animación y saltar de fotograma:

package {
import flash.display.MovieClip;
import flash.events.Event;
//
public class FrameInOut extends MovieClip {

public var goto:uint;

public function FrameInOut() {
MovieClip(this.parent).currentFrameClip=this;
frameIntro();
}
public function gotoFrame(frame:uint):void {
if (frame!=MovieClip(this.parent).currentFrame) {
goto=frame;
this.gotoAndStop("on");
this.addEventListener(Event.ENTER_FRAME,avanzaFrame);
}
}
//-----------------------------------------------------
private function frameIntro():void {
this.gotoAndStop("out");
this.addEventListener(Event.ENTER_FRAME,retrocedeFrame);
}
private function retrocedeFrame(e:Event):void {
if (this.currentLabel=="on") {
this.removeEventListener(Event.ENTER_FRAME,retrocedeFrame);
} else {
this.prevFrame();
}
}
private function avanzaFrame(e:Event):void {
if (this.currentLabel=="out") {
this.removeEventListener(Event.ENTER_FRAME,avanzaFrame);
MovieClip(this.parent).gotoAndStop(goto);
} else {
this.nextFrame();
}
}
}
}

Esta clase lo que hace es guardar el valor del fotograma al que debe de saltar. Luego reproduce la animación de salida desplazandose desde el Label "on" al Label "out", y es entonces cuando llama ejecutar el gotoAndStop que hace cambiar de fotograma.

El contructor de la clase también tiene una llamada a una función que hace reproducir la animación de entrada creandose así la transición de un fotograma al otro.

Aquí puedes descargarte el archivo.

Comparte:

Visualizar menús desplegables HTML por encima de películas Flash

admin — Fri, 31 Jul 2009 20:29:44 +0000

Este es otro tip "only for dummies", que es muy sencillo pero que da dolores de cabeza a la gente que apenas se inicia en el mundo de Ajax únicamente utilizando los códigos automáticos de Spry que trae Dreamweaver.

El problema que muchos se encuentran es que los menús desplegables les quedan por debajo de las peliculas Flash, aun estando está en un index inferior.

Esto tiene una solución muy sencilla, y pasa por añadirle la propiedad wmode de la pelicula Flash a valor invisible.

De manera que si estamos utilizando SwfObject para colocar el SWF, utilizariamos este código:

Esta línea de código es suficiente para resolver el problema.

Aqui el ejemplo, por si alguien lo quiere ver

Comparte:

Sustituir un SWF por otro sin refrescar el HTML con Ajax

admin — Thu, 30 Jul 2009 23:16:11 +0000

En este sencillo ejemplo mostraré como sustituir un archivo SWF de una página HTML por otro sin necesidad de refrescar la página. (ejemplo)

Para ello utilizaremos SwfObject y JQuery. En realidad JQuery no haria falta utilizarlo ya que quien sustituirá el SWF será SwfObject y podriamos hacer la llamada con una simple funcion Javascript. Pero nunca está de más ver un poco de Ajax

Para empezar nos descargaremos las librerias:

.
Lo primero será colocar nuestra pelicula SWF dentro de la página HTML con SwfObject de la forma típica. Creando una DIV y asignandole ahí la pelicula SWF. Lo haremos creando una función que reciba el parámetro de la URL del SWF para poder volver a llamar esa función más adelante:

Ahora crearemos unos cuantos links con los que queremos cambiar de pelicula SWF pero sin cambiar de página HTML. Los colocaremos en otro DIV y asignaremos a cada enlace un ID diferente:

"botonera">

"a" href="#">a.swf
- "b" href="#">b.swf
- "c" href="#">c.swf

Podríamos hacer que cada enlace volviera a ejecutar la función Javascript y listo, pero haremos el ejemplo más c00l utilizando JQuery.

Primero definiremos un objeto en el que guardaremos una relación entre los ID de los enlaces y la pelicula SWF que han de abrir.

var swfRef = {
a: "a.swf",
b: "b.swf",
c: "c.swf"
};

Y por último crearemos una función de JQuery que asignará a cada enlace la llamada a la función Javascript pasandole el parámetro que toca. Tambien sustituiremos la primera llamada.

$(function(){
$.each(swfRef, function(i, val){
$("#" + i).click(function(){
putSWF(val);
});
});
$("#a").click();
});

Y listo, ahora cada enlace sustituye el SWF por otro dentro de la misma página.

Aqui se puede ver el ejemplo: http://www.cristalab.com/zguillez/ajax/putswf/index.html

Y el código completo:

"botonera">

"a" href="#">a.swf
- "b" href="#">b.swf
- "c" href="#">c.swf

"flash">

Comparte:

Panel de zoom de imágenes en Flex

admin — Mon, 13 Apr 2009 21:04:16 +0000

Este ejemplo es, igual que hice en el post anterior, un ejemplo que he adaptado a Flex desde un ejemplo que hice hace tiempo para Flash. Se trata de un panel donde se ve un zoom de una parte de una imagen.

Este es el ejemplo montado en Flex:

Y este es el código utilizado para la película principal:

xml version="1.0" encoding="utf-8"?>
"http://www.adobe.com/2006/mxml"
xmlns:ui="*"
layout="absolute"
creationComplete="ini()"
width="505"
height="260">

[CDATA[
import ZoomFx;
private var _zoom:ZoomFx;

private function ini():void
{
_zoom=new ZoomFx(this, fotoZoom, panelZoom);
}
]]>

"0"
verticalCenter="0">
"fotoZoom"/>
"panelZoom"/>

Este sería el componente que contiene la foto en grande:

xml version="1.0" encoding="utf-8"?>
"http://www.adobe.com/2006/mxml"
   width="350"
   height="250"
   borderStyle="solid"
   borderThickness="1"
   borderColor="#000000"
   horizontalScrollPolicy="off"
   verticalScrollPolicy="off">
"foto"
   scaleContent="false">
img/Waterfall.jpg

Y este el componente que contiene el panel de preview:

xml version="1.0" encoding="utf-8"?>
"http://www.adobe.com/2006/mxml"
   width="140"
   height="100"
   borderStyle="solid"
   borderThickness="1"
   borderColor="#000000"
   horizontalScrollPolicy="off"
   verticalScrollPolicy="off">
"foto"
   scaleContent="true"
   width="140"
   height="100"
   horizontalCenter="0"
   verticalCenter="0">
img/Waterfall.jpg

"0"
   y="0"
   width="70"
   height="50"
   backgroundColor="#FF0000"
   backgroundAlpha="0.5"
   borderStyle="solid"
   borderThickness="1"
   borderColor="#FF0000"
   id="zoomDrag">

Solo quedaría la clase de que controla el efecto:

package
{
import flash.events.Event;
import flash.events.MouseEvent;

import mx.containers.Canvas;
import mx.controls.Image;
import mx.controls.Alert;
import mx.core.UIComponent;

public class ZoomFx
{
private var _stage:UIComponent;
private var _fotoZoom:UIComponent;
private var _panelZoom:UIComponent;
private var _distX:Number;
private var _distY:Number;
private var _porcentajeX:Number;
private var _porcentajeY:Number;

//----------------------------------------------------
public function ZoomFx(stage:UIComponent, fotoZoom:UIComponent, panelZoom:UIComponent)
{
_stage=stage;
_fotoZoom=fotoZoom;
_panelZoom=panelZoom;

iniZoomDrag();
}

private function iniZoomDrag():void
{
var drag:Canvas=_panelZoom.getChildByName("zoomDrag") as Canvas;
drag.addEventListener(MouseEvent.MOUSE_DOWN, onStartDrag);
drag.addEventListener(MouseEvent.MOUSE_UP, onStopDrag);
drag.addEventListener(MouseEvent.MOUSE_OUT, onStopDrag);
}

private function onStartDrag(e:Event):void
{
var canvas:Canvas=e.target as Canvas;
canvas.startDrag();
_stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseDragMove);
}

private function onStopDrag(e:Event):void
{
var canvas:Canvas=e.target as Canvas;
canvas.stopDrag();
_stage.removeEventListener(MouseEvent.MOUSE_MOVE, onMouseDragMove);
}

private function onMouseDragMove(e:Event):void
{
calculaDist();
mueveVisorZona();
controlaPosiciones();
}

//-------------------------------------------------------------
private function calculaDist():void
{
var drag:Canvas=_panelZoom.getChildByName("zoomDrag") as Canvas;
var foto:Image=_fotoZoom.getChildByName("foto") as Image;

_porcentajeX=100 / (foto.width / _panelZoom.width);
_porcentajeY=100 / (foto.height / _panelZoom.height);

drag.width=_fotoZoom.width * _porcentajeX / 100;
drag.height=_fotoZoom.height * _porcentajeY / 100;

_distX=drag.x * 100 / _porcentajeX;
_distY=drag.y * 100 / _porcentajeY;

_distX=(_distX <0) ? 0 : _distX;
_distY=(_distY <0) ? 0 : _distY;
}

private function mueveVisorZona():void
{
var drag:Canvas=_panelZoom.getChildByName("zoomDrag") as Canvas;
var foto:Image=_fotoZoom.getChildByName("foto") as Image;
foto.x=-_distX;
foto.y=-_distY;
}

private function controlaPosiciones():void
{
var drag:Canvas=_panelZoom.getChildByName("zoomDrag") as Canvas;
var foto:Image=_fotoZoom.getChildByName("foto") as Image;

if (drag.x <0)
{
drag.x=0;
}
else if (drag.x> _panelZoom.width - drag.width)
{
drag.x=_panelZoom.width - drag.width;
}
if (drag.y <_panelZoom.y)
{
drag.y=_panelZoom.y;
}
else if (drag.y> _panelZoom.y + _panelZoom.height - drag.height)
{
drag.y=_panelZoom.y + _panelZoom.height - drag.height;
}

if (foto.x> 0)
{
foto.x=0;
}
else if (foto.x <_fotoZoom.width - foto.width)
{
foto.x=_fotoZoom.width - foto.width;
}
if (foto.y> 0)
{
foto.y=0;
}
else if (foto.y <_fotoZoom.height - foto.height)
{
foto.y=_fotoZoom.height - foto.height;
}
}

}
}

Comparte:

Ejemplo de Zoom con lupa en Flex

admin — Sat, 11 Apr 2009 02:46:07 +0000

Hace un tiempo escribí un ejemplo de zoom sobre una imagen con Flash. Justo ahora me acaban de preguntar como adaptar ese ejemplo a una aplicación Flex.

Adaptar ese ejemplo es fácil, ya que el código actionscript se puede reutilizar prácticamente igual. Lo único que hay que tener en cuenta es que no vamos a trabajar con un MovieClip con una máscara sino con componentes mxml de Flex.

Así es como quedará el ejemplo montado en Flex:

Desplaza el mouse sobre la imagen para mover la lupa

Esta seria nuestra aplicación Flex:

xml version="1.0" encoding="utf-8"?>
"http://www.adobe.com/2006/mxml"
layout="absolute"
xmlns:ui="*"
creationComplete="ini()">

[CDATA[
import LupaFx;
private var _lupa:LupaFx;
private function ini():void
{
_lupa=new LupaFx(this, foto, lupa);
}
]]>

"foto" scaleContent="true" horizontalCenter="0" verticalCenter="0" width="350" height="250">
img/Waterfall.jpg

"lupa"
x="0"
y="0"/>

El componente que utilizaremos como lupa:

xml version="1.0" encoding="utf-8"?>
"http://www.adobe.com/2006/mxml"
width="100" height="100" borderStyle="solid" borderThickness="4"
borderColor="#FF0000" horizontalScrollPolicy="off" verticalScrollPolicy="off">
"foto" scaleContent="false" y="0" x="0">
img/Waterfall.jpg

Y la clase de actionscript que controlará el efecto:

package
{
import flash.events.MouseEvent;

import mx.core.UIComponent;

public class LupaFx
{
private var _stage:UIComponent;
private var _foto:UIComponent;
private var _lupa:UIComponent;
private var _distX:Number;
private var _distY:Number;
private var _porcentajeX:Number;
private var _porcentajeY:Number;
//----------------------------------------------------
public function LupaFx(stage:UIComponent, foto:UIComponent, lupa:UIComponent)
{
_stage=stage;
_foto=foto;
_lupa=lupa;
stage.addEventListener(MouseEvent.MOUSE_MOVE, lupaMouseMove);
lupaMouseMove();
}
//----------------------------------------------------
private function lupaMouseMove(event:MouseEvent=null):void
{
calculaDist();
mueveLupa();

_lupa.x=_foto.mouseX + _foto.x - _lupa.width / 2;
_lupa.y=_foto.mouseY + _foto.y - _lupa.height / 2;

if (_lupa.x <_foto.x)
{
_lupa.x=_foto.x;
}
else if (_lupa.x> _foto.x + _foto.width - _lupa.width)
{
_lupa.x=_foto.x + _foto.width - _lupa.width;
}
if (_lupa.y <_foto.y)
{
_lupa.y=_foto.y;
}
else if (_lupa.y> _foto.y + _foto.height - _lupa.height)
{
_lupa.y=_foto.y + _foto.height - _lupa.height;
}
}
//----------------------------------------------------
private function calculaDist():void
{
_porcentajeX=100 / (_lupa.getChildByName("foto").width / (_foto.width - _lupa.width / 2));
_porcentajeY=100 / (_lupa.getChildByName("foto").height / (_foto.height - _lupa.height / 2));

_distX=(_lupa.x - _foto.x) / _porcentajeX * 100;
_distY=(_lupa.y - _foto.y) / _porcentajeY * 100;
}
//----------------------------------------------------
private function mueveLupa():void
{
_lupa.getChildByName("foto").x=-_distX;
_lupa.getChildByName("foto").y=-_distY;
}
}
}

Comparte:

Acceder a los itemRenderer de un componente lista en Flex

admin — Sun, 22 Mar 2009 03:45:30 +0000

Este es un tip sencillo pero que me dió algún que otro dolor de cabeza al querer aplicar unos efectos sobre los componentes utilizados como itemRenderes dentro de un componente tipo lista en Flex. Se trata de cómo poder acceder a estos componentes para manipular su contenido a través de Actionscript.

Para acceder al componente del itemRenderer en concreto utilizaremos indexToItemRenderer, pasándole como parámetro el index del ítem que queremos obtener.

El detalle importante que debemos tener en cuenta es que no podemos referenciar un objeto que no sea visible dentro de la zona del scroll, ya que hasta entonces devolvería valor null. Para ello deveremos realizar la comprobación con isItemVisible, y ejecutar las acciones solo sobre los componentes visibles.

var total:uint = tileList.dataProvider.length;
for (var i:uint = 0; i )
{
if (tileList.isItemVisible(tileList.dataProvider[i]) == true)
{
var item:Object = tileList.indexToItemRenderer(i);
// resto de implementación sobre los componentes
}
}

Comparte:

Mostrar una alerta antes del cierre de una aplicación AIR

admin — Tue, 27 Jan 2009 01:59:31 +0000

En este ejemplo mostraré como crear una ventana de alerta cuando le demos al botón de cerrar en una aplicación AIR, teniendo que validar el cierre evitando que se cierre directamente. De esta manera podemos controlar que el usuario cierre la aplicación si haber realizado una operación necesaria, por ejemplo guardar los cambios realizados en el caso de tratarse de una a aplicación que edite documentos.

Lo primero que deberemos hacer es colocar la función a realizar cuando se detecte el evento de cierre de la aplicación (osea, cuando el usuario cierra la aplicación).

"http://www.adobe.com/2006/mxml" layout="absolute" closing="cerrarApp(event)">

Ahora escribiremos la función. El punto importante aquí es como evitar el cierre de la aplicación, ya que el usuario realmente a clicado en el botón de cerrar. Esto lo conseguimos con el método preventDefault() de la clase Event. Con este método conseguimos que el evento no ejecute las funciones por defecto y por lo tanto no se cierra la aplicación. Lo que haremos en su lugar es abrir una ventana de Alert.

public function cerrarApp(e:Event):void
{
e.preventDefault();

Alert.yesLabel = "Si";

Alert.show("¿Realmente quiere salir?","Salir aplicación", Alert.YES | Alert.NO, null, cerrar, null, 2);
}

Con yesLabel decimos que aparezca el texto "Si" en el botón de validar en lugar de "Yes". Y con el 2 al final de los parámetros decimos que el botón seleccionado por defecto sea el segundo, osea el "No".

También le estamos indicando que al clicar sobre cualquiera de los botones se ejecute la función "cerrar" que es la siguiente:

private function cerrar(e:CloseEvent):void
{
if(e.detail == Alert.YES)
{
this.nativeApplication.exit();
}
}

Donde le estamos indicando que si el botón seleccionado es el "Si" entonces cierre la aplicación. En el caso de seleccionar el "No" no se ejecuta nada y por lo tanto la aplicación sigue abierta.

[h3]Segundo ejemplo[/h3]

El código anterior se ejecutaría siempre que le demos al icono de cerrar aplicación. Pero lo interesante es poder controlar cuando queremos mostrar esa advertencia.

Por ejemplo en el caso de tener una aplicación que sea un editor de texto. Si le damos al botón de cerrar la aplicación teniendo cambios sin guardar mostraremos el Alert, pero en el caso de haber guardado los cambios previamente cerraremos directamente la aplicación.

Primero crearemos una variable booleana que controlará si la aplicación se cierra automáticamente o requiere mostrar la advertencia.

private var cierre:Boolean = true;

En la función que se ejecuta al cerrar la aplicación colocaremos un condicional que detecte el estado de esa variable.

private function cerrarApp(e:Event):void
{
e.preventDefault();

if(cierre == false)
{
Alert.yesLabel = "Si";
Alert.show("¿Desea guardar los cambios antes de salir?","Salir aplicación", Alert.YES | Alert.NO | Alert.CANCEL, null, cerrar, null, 3);
}
else
{
this.nativeApplication.exit();
}
}

Lógicamente esa función "cierre" la deberemos controlar con el resto de funciones de la aplicación. Es decir, todas las funciones que realicen cualquier cambio que deba ser guardado deberán colocar esa variable a "false", y la función que realice el guardado de datos deberá colocar la variable a "true".

La función de cierre quedaría asi:

private function cerrar(e:CloseEvent):void
{
if(e.detail == Alert.YES)
{
guardarDatos();
this.nativeApplication.exit();
}
else if(e.detail == Alert.NO)
{
this.nativeApplication.exit();
}
}

De manera que si clicamos "Si" ejecutaríamos la función que nos guarda los datos y cerraríamos después la aplicación, si clisásemos "No" cerraríamos directamente y si clisásemos "Cancel" entonces no se ejecutaría nada y no cerraríamos la aplicación.

Comparte:

Cómo personalizar el icono del panel de Alerta de Flex

Ordenar elementos de un Vector en Actionscript 3

admin — Thu, 22 Jan 2009 16:54:29 +0000

En este ejemplo explicaré como ordenar elementos internos de un objeto de clase Vector en Actionscript 3. Para ordenar los elementos en realidad se realiza de igual manera que en un Array. Únicamente deberemos escribir una función que compare lo elementos según el orden que nos interese.

El valor que nos ha de devolver la función que realiza la comparación deberá ser:

1: Si el primer valor es superior al segundo
-1: si el primer valor es inferior al segundo
0: Si los valores son iguales

De manera que si creamos un Vector con 10 numero aleatorios:

var vector:Vector. = new Vector.();
for (var i:int = 0; i <10; i++)
{
vector.push(Math.random() * 100);
}
trace(vector); //25,19,69,95,57,78,59,86,2,97

Si ahora lo quisiésemos ordenar de forma ascendente haríamos lo siguiente:

function ascendente(x:uint, y:uint):int
{
return (x>= y)?1 :-1;
}
vector.sort(ascendente);
trace(vector); //2,19,25,57,59,69,78,86,95,97

Y lo mismo para ordenarlo de forma descendente:

function descendente(x:uint, y:uint):int
{
return (x )?1 :-1;
}
vector.sort(descendente);
trace(vector); //97,95,86,78,69,59,57,25,19,2

Comparte:

Otener parámetros en eventos de Actionscript 3

admin — Tue, 18 Nov 2008 22:03:42 +0000

Cuando lanzamos un evento en Actionscript 3, por ejemplo de la clase MouseEvent, ponemos recuperar una serie de parámetros lanzados con ese evento.

Por ejemplo, en este código:

boton.addEventListener(MouseEvent.MOUSE_DOWN, onBotonEvent);

function onBotonEvent(e:MouseEvent):void
{
trace(e);
}

El trace() nos mostraría el evento que ha lanzado la función mostrando también todos los parámetros. En este caso serían estos:

MouseEvent type="mouseDown" bubbles=true cancelable=false eventPhase=2 localX=43 localY=30 stageX=170.55 stageY=106 relatedObject=null ctrlKey=false altKey=false shiftKey=false delta=0

Recuperar estos parámetros y saber con detalle el evento que ha lanzado la función nos puede resultar muy útil en muchos casos.

por ejemplo, su quisiésemos ejecutar una acción u otra al clicar sobre el botón dependiendo si estamos pulsando la tecla podríamos recuperar ese parámetro del evento:

boton.addEventListener(MouseEvent.MOUSE_DOWN, onBotonEvent);
function onBotonEvent(e:MouseEvent):void
{
e.ctrlKey == true ? accion1() : accion2();
}

Aquí, si clicamos al botón sin tener pulsada la tecla ejecutaremos la función accion2, mientras que con el mismo clic con la tecla pulsada ejecutaríamos la función accion1.

También podemos utilizar este recurso para asignar la misma función a varios eventos y poder asignar diferentes parámetros a la función dependiendo del tipo de evento:

import fl.motion.Color;
boton.addEventListener(MouseEvent.ROLL_OVER, onBotonEvent);
boton.addEventListener(MouseEvent.ROLL_OUT, onBotonEvent);
boton.addEventListener(MouseEvent.MOUSE_DOWN, onBotonEvent);
boton.addEventListener(MouseEvent.MOUSE_UP, onBotonEvent);

function onBotonEvent(e:MouseEvent):void
{
var code:uint;
e.type == "rollOver" ? code = 0xCCCCCC : null;
e.type == "rollOut" ? code = 0x999999 : null;
e.type == "mouseDown" ? code = 0x666666 : null;
e.type == "mouseUp" ? code = 0xCCCCCC : null;

var color:Color = new Color();
color.setTint(code, 1);
e.target.transform.colorTransform = color;
}

En este ejemplo, todos los eventos del botón ejecutan la misma función pero dependiendo de cada uno se coloreará el clip de un color u otro.

Comparte:

Listar archivos de un directorio web con PHP y XML

admin — Mon, 27 Oct 2008 15:37:50 +0000

Este es un sencillo script de PHP que nos permite generar un archivo XML con el listado de todos los archivos y carpetas que esten contenidos dentro del directorio en el que hemos situado el archivo PHP.

Esto nos puede resultar útil para realizar galerías fotográficas en las que queremos acceder a todas las imágenes de un directorio y queremos poder subir o borrar archivos. El archivo XML siempre estará actualizado a los ficheros del servidor.

El archivo PHP es el siguiente. Lo llamaremos list.php y lo subiremos al servidor dentro de la carpeta que nos interese listar.

$dir = "./";

echo "\n";
echo " \n";

if (is_dir($dir))
{
   if ($gd = opendir($dir))
{
   while (($archivo = readdir($gd)) !== false)
{
if ($archivo != "." & $archivo != ".." & $archivo != "list.php")
{
if (is_dir($archivo))
{
      echo " $archivo\n";
}
else
{
      echo " $archivo\n";
}
}
   }
   closedir($gd);
   }
}

echo " \n";
echo "\n";
?>

El script lo único que hace es recorrer todos los elementos de la carpeta en la que está situado y a base de "echos" formatea el XML.

Si visualizamos este archivo desde el navegador y miramos el código resultante este sería un archivo XML de este estilo:

'UTF-8' standalone='yes' version='1.0'>

img_001.jpg
img_002.jpg
img_003.jpg
img_004.jpg
img_005.jpg
thumbs
hires

De esta manera si quisiésemos, por ejemplo, listar el contenido de imágenes disponibles de este directorio dentro de un componente List de Flash haríamos lo siguiente:

import fl.data.DataProvider;

var _URLLoader = new URLLoader();
var _URLRequest = new URLRequest();

_URLRequest.url = "/img/list.php";
_URLLoader.load(_URLRequest);
_URLLoader.addEventListener(Event.COMPLETE, onListComplete);

Cargamos el archivo PHP como si de un XML se tratase, y de ahí lo convertimos en el dataProvider del componente.

Comparte: