Cómo crear transiciones entre fotogramas en Flash
Hace unos días me preguntaron como crear transiciones entre fotogramas en Flash. Esto es una tarea bastante sencilla de implementar así que aprovecho para explicarla en forma de Tip.
Lo que se pretende conseguir es que al cambiar de fotograma, los elementos del fotograma actual desaparezcan de forma animada antes de saltar al siguiente fotograma. Como se ve en el ejemplo:
Clicka en los botones de colores
Esta sencilla película está estructurada en varios fotogramas con un elemento diferente en cada uno de ellos y una serie de botones que nos hacen saltar de uno a otro.
La idea del ejemplo es que cada fotograma esté contenido en un MovieClip que contenga a su vez la animación de entrada y salida. Y por código haremos que se reproduzcan estas animaciones al cambiar de fotograma.
En el primer fotograma del MovieClip tendremos todo su contenido tal cual nos interese tener en pantalla, y apartir del segundo fotograma haremos la animación de entrada y salida.
Para este ejemplo la animación de entrada y salida será la misma interpolación de movimiento que reproduciremos adelante o hacia atrás según sea el caso.
Para poder referenciar el código colocaremos un Label “on” en el primer frame de la animación, un Label “anim” en los fotogramas internos de la animación, y un Label “out” en el último fotograma de la animación.
[h3]Ahora vayamos al código:[/h3]
Empezaremos por la clase Main.as, que es la clase de la pelicula y donde asignaremos los comportamientos a los botones:
- package {
- import flash.display.MovieClip;
- import flash.events.MouseEvent;
- //
- public class Main extends MovieClip {
- public var currentFrameClip:MovieClip;
- public function Main() {
- this.boton1.addEventListener(MouseEvent.CLICK,gotoFrame);
- this.boton2.addEventListener(MouseEvent.CLICK,gotoFrame);
- this.boton3.addEventListener(MouseEvent.CLICK,gotoFrame);
- this.boton4.addEventListener(MouseEvent.CLICK,gotoFrame);
- this.stop();
- }
- private function gotoFrame(e:MouseEvent):void {
- switch (e.currentTarget) {
- case boton1 :
- currentFrameClip.gotoFrame(1);
- break;
- case boton2 :
- currentFrameClip.gotoFrame(2);
- break;
- case boton3 :
- currentFrameClip.gotoFrame(3);
- break;
- case boton4 :
- currentFrameClip.gotoFrame(4);
- break;
- }
- }
- }
- }
Aquí lo único que hacemos es que los botones de la película hagan ejecutar al MovieClip, referenciado desde una variable “currentFrameClip“, un método llamado “gotoFrame“, que como su nombre indica nos hará saltar al fotograma pasado como parámetro.
Vayamos ahora a la clase que asignaremos a cada uno de los MovieClip de los fotogramas y que es la que hará reproducir la animación y saltar de fotograma:
- package {
- import flash.display.MovieClip;
- import flash.events.Event;
- //
- public class FrameInOut extends MovieClip {
- public var goto:uint;
- public function FrameInOut() {
- MovieClip(this.parent).currentFrameClip=this;
- frameIntro();
- }
- public function gotoFrame(frame:uint):void {
- if (frame!=MovieClip(this.parent).currentFrame) {
- goto=frame;
- this.gotoAndStop("on");
- this.addEventListener(Event.ENTER_FRAME,avanzaFrame);
- }
- }
- //-----------------------------------------------------
- private function frameIntro():void {
- this.gotoAndStop("out");
- this.addEventListener(Event.ENTER_FRAME,retrocedeFrame);
- }
- private function retrocedeFrame(e:Event):void {
- if (this.currentLabel=="on") {
- this.removeEventListener(Event.ENTER_FRAME,retrocedeFrame);
- } else {
- this.prevFrame();
- }
- }
- private function avanzaFrame(e:Event):void {
- if (this.currentLabel=="out") {
- this.removeEventListener(Event.ENTER_FRAME,avanzaFrame);
- MovieClip(this.parent).gotoAndStop(goto);
- } else {
- this.nextFrame();
- }
- }
- }
- }
Esta clase lo que hace es guardar el valor del fotograma al que debe de saltar. Luego reproduce la animación de salida desplazandose desde el Label “on” al Label “out”, y es entonces cuando llama ejecutar el gotoAndStop que hace cambiar de fotograma.
El contructor de la clase también tiene una llamada a una función que hace reproducir la animación de entrada creandose así la transición de un fotograma al otro.
Aquí puedes descargarte el archivo.
Compártelo:
Visto 22.496 veces
Muchas, muchísimas gracias camarada ZGuillez, se lo agradezco.
Ya le comentaré cuando lo pruebe.
Saludos
Sencillo y práctico. Buen tip 😉
hola guille, he seguido tu tutorial, estoy empezando ahora con as3, (solo sabia java jeje), lo que no entiendo de este tutorial como haces el uso de las clases sin importarlas,(al menos no lo diviso en el fla).Un saludo.
@samuel:
La clase Main está asignada a la película desde el panel de propiedades, y la clase del MovieClip se asigna en el menú de vinculación desde la biblioteca
saludos
muchas gracias, ya he aprendido algo nuevo, para no tener que estar importando ni declarando.
tengo una duda.. el mc q carga al clicar en los botones, es siempre el mismo, lo que cambia es la “tinta”. entonces si intento poner mc diferentes segun el fotograma.. m da error “TypeError: Error #1009: No se puede acceder a una propiedad o a un método de una referencia a un objeto nulo.
at FrameInOut/gotoFrame()
at Main/gotoFrame()”
haber si m puedes decir q tengo q modificar para q me funcione con diferentes mc.. m está dando muchos dolores d cabeza intentarlo sola.. stoy empezando con as3… muchisimas gracias!!
Me estaba rompiendo el bocho para saber de donde enlazabas la clase del MC!…
gracias!..
Hola, he leído el tutorial y lo que no me queda claro es donde se colocan los botones y como mando a llamar los otros movieclips, es decir ya sé que es a través de las clases pero no he podido resolverlo, alguien puede orientarme…saludos!!!
Creo que Distriker no lo probo! XD